网站搜索

我把大写锁定键重新映射为“超级键”，并且我的快捷方式数量翻倍了

在一天中的工作中，我会使用许多 Windows 键盘快捷键，无论是用于文件资源管理器的 Win + E 还是用于任务管理器的 Ctrl + Shift + Esc。然而，当我想为常用的应用程序和操作添加自定义快捷键时，好的组合不是被系统占用，就是已经被其他应用程序使用了。

解决方法很简单。你可以将一个很少使用的键重新映射为超级键。通过简单的注册表调整和一个轻量级脚本，我获得了一整层在任何地方都可用且不会冲突的快捷键。如果你曾经想要更多的键盘快捷方式，又不想麻烦地记住哪些会冲突，这种方法值得花几分钟来设置。

Hyper键到底是什么？

将四个修饰键组合成一个强大的快捷键

超级键是一个单独的按键，它发送一个修饰键组合——通常是 Ctrl + Shift + Alt + Win。由于几乎没有应用程序保留这个四键组合，使用它创建的任何快捷键都不会与现有快捷键冲突。你可以为自定义快捷键获得一个干净的起点。

这个概念起源于 Unix 系统，并在寻找更多修饰键选项的 macOS 高级用户中获得了流行。默认情况下，Windows 没有原生的 Hyper 键，并且还将四修饰键组合保留用于打开 Office 应用程序。

大写锁定键显然是设置超键（Hyper Key）的最佳选择。它位于主键区，你的左手小指自然就放在这里。将其重新映射为超键，可以把这一块原本空闲的键盘空间变为有用的功能，同时不失去大写锁定功能。这是因为你仍然可以配置按下时切换大写锁定的功能。实际的好处是，你不再需要去寻找那些可能有效的复杂按键组合，而是可以从头开始。Hyper + E、Hyper + T 和 Hyper + B 可以被分配为打开你选择的应用或操作。

我最初尝试过使用 PowerToys 键盘管理器来提高效率，但它无法将单个按键同时映射到所有四个修饰键。不过，如果你只想让 Caps Lock 作为两个修饰键，PowerToys 完全可以使用。要实现真正的超级键，还是得用 AutoHotkey。

首先，关闭 Windows Office 快捷方式

运行注册表修复

在设置 Hyper Key 之前，您需要处理 Windows 中的一个奇怪问题。微软默认保留 Ctrl + Shift + Alt + Win 组合键来打开 Office 应用程序。当您同时按下这四个修饰键时，即使不使用 Office，也会打开 Microsoft Copilot 或浏览器中的 Office 365 登录页面。

这意味着任何 Hyper 键快捷键都会触发此行为，而不是预期的操作。解决方法是一条注册表命令，将此快捷键重定向为无操作。在进行任何更改之前，请确保备份注册表。

  1. 按下 Win + X 并选择 终端（管理员）。

  2. 粘贴以下命令并按回车：

    REG ADD HKCU\Software\Classes\ms-officeapp\Shell\Open\Command /t REG_SZ /d rundll32
  3. 你应该会看到消息：“操作已成功完成。”

更改立即生效，因此无需重新启动计算机。要验证，请按 Ctrl + Shift + Alt + Win。如果没有任何反应，则可以继续下一步。如果 Copilot 或 Office 仍然打开，请以管理员身份再次运行该命令。

此调整仅关闭四修饰键快捷方式。它不会影响单个 Office 应用程序或其他任何 Windows 快捷方式。

我如何用 AutoHotkey 设置超级键

我保留了按下切换的大写锁定键

AutoHotkey 是一个免费的 Windows 自动化脚本工具。它是将大写锁定键真正变成超级键（同时按下 Ctrl + Shift + Alt + Win）的唯一可靠方式。不要担心脚本部分；设置很简单。

  1. 从官方网站下载并安装 AutoHotkey v2。
  2. 右键点击桌面并选择 新建 > AutoHotkey 脚本。
  3. 将文件命名为类似 HyperKey.ahk 的名字，并在记事本中打开它。
  4. 删除任何默认内容，粘贴脚本（我在下面提供了），然后保存。
  5. 以管理员身份运行该文件。
#Requires AutoHotkey v2.0

*CapsLock::
{
    Send("{Ctrl down}{Shift down}{Alt down}{LWin down}")
    KeyWait("CapsLock")
    Send("{Ctrl up}{Shift up}{Alt up}{LWin up}")
}

当脚本运行时，系统托盘会出现一个绿色的“H”图标。现在按住Caps Lock，它会同时发送四个修饰键。松开时，修饰键也会被释放，就像普通的修饰键一样。

这个基础脚本完全取代了大写锁定键，但如果你偶尔需要切换大小写，请改用下面的脚本。它区分按下和长按——快速按下并释放以切换大写，长按则激活超级键。

#Requires AutoHotkey v2.0

*CapsLock::
{
    startTime := A_TickCount
    Send("{Ctrl down}{Shift down}{Alt down}{LWin down}")
    KeyWait("CapsLock")
    Send("{Ctrl up}{Shift up}{Alt up}{LWin up}")
    
    if (A_TickCount - startTime < 200) && (A_PriorKey = "CapsLock")
    {
        SetCapsLockState(!GetKeyState("CapsLock", "T"))
    }
}

200毫秒的阈值对大多数人来说效果很好。如果你觉得太敏感，可以增加这个数值。

要让脚本在启动时运行，按 Win + R，输入 shell:startup，然后按 回车。将 HyperKey.ahk 文件复制到此文件夹中。Windows 每次登录时都会自动启动它。

我最喜欢使用新超级键的快捷方式

我已经开始每天使用它们了

一旦 Hyper Key 脚本正在运行，你可以通过编辑同一个 .ahk 文件来添加自定义快捷键。每个快捷键使用一个简单的语法：#^!+ 后跟一个字母，其中 # 是 Win 键，^ 是 Ctrl 键，! 是 Alt 键，+ 是 Shift 键。它们组合在一起就表示 Hyper Key。以下是我使用的快捷键：

快捷方式

目的

超 + T

打开 Windows 终端。我经常使用命令行，这比去找它方便多了。

Hyper + E

打开文件资源管理器到我的工作文件夹，而不是默认的主页视图。

超 + B

启动我的浏览器。很简单，但我一天要用好几十次。

超 + N

打开记事本，用于快速记录笔记或粘贴我需要清理的文本。

Hyper + C

启动计算器。

超 + S

打开 Spotify。

超 + Q

关闭活动窗口。这比按 Alt + F4 快。

Hyper + D

打开下载文件夹。

其中一些快捷方式可以处理没有方便内置替代方法的任务。要添加这些快捷方式：

  1. 右键点击系统托盘中的绿色“H”图标，然后选择退出。
  2. 在记事本中打开 HyperKey.ahk 文件。
  3. 在现有脚本下面添加以下脚本。
  4. 再次以管理员身份运行。
; Hyper+T: Open Windows Terminal
#^!+t::Run("wt.exe")

; Hyper+E: Open File Explorer to a specific folder (change the path to your working folder)
#^!+e::Run("explorer.exe C:\Users\PC\Downloads\windows.day")

; Hyper+B: Open default browser
#^!+b::Run("https://")

; Hyper+N: Open Notepad
#^!+n::Run("notepad.exe")

; Hyper+C: Open Calculator
#^!+c::Run("calc.exe")

; Hyper+S: Open Spotify
#^!+s::Run("spotify:")

; Hyper+Q: Close active window
#^!+q::WinClose("A")

; Hyper+D: Open Downloads folder
#^!+d::Run("explorer.exe shell:Downloads")

以分号开头的行是注释。AutoHotkey 会忽略它们，但可以帮助你记住每个快捷键的作用。对于 Hyper + E，你可以将路径替换为你想要打开的任何文件夹。下载文件夹的快捷键让我不必每次都通过文件资源管理器来查找最近下载的文件。从几个你经常打开的应用程序的快捷键开始，然后随着肌肉记忆的建立再逐步增加。

超级键只是起点

接下来去哪儿

Hyper Key 的设置只需几分钟，但其价值取决于你在其基础上构建的内容。一旦你熟悉之后，可以考虑为特定文件夹添加快捷键、以预设窗口位置启动应用程序，或者通过 AutoHotkey 触发多步骤自动化操作。

你也可以尝试重新映射其他不常用的键，比如滚锁键、插入键，甚至是右Alt键。逻辑是一样的：如果一个键没有发挥作用，就让它发挥作用。

相关文章